Sarvegne
Une fiction interactive par Eric Forgeot (2006) - Code source Inform 7
Home pageContents
Previous
Next
Complete text Part 4 - Au delà
Final is a scene. Final begins when Anita is in maisonanita for the first time.
ReseauGrottes is a region. Grottes and Grottes2 are in ReseauGrottes.
Before going nowhere from ReseauGrottes:
if bibliotheque is not visited
begin;
say "";
otherwise;
say "Vous risquez de vous perdre si vous allez en dehors des lieux répertoriés et balisés par Anita.";
end if.
CampAncien is a room. The printed name of CampAncien is "Un camp".
The description of CampAncien is "[if location is not visited]Après plusieures lieues de marche, vous arrivez à proximité d[']un campement.[end if]Vous êtes dans un camp, caché dans le désert, mais en bordure d[']une forêt. Il n[']y a plus personne ici, mais vous voyez des chariots et des arcs abandonnés.".
accessoiresCamp is scenery in campancien. Understand "chariot/chariots/camp/arc/arcs" as accessoiresCamp. The description of accessoirescamps is "Divers objets appartenant à la tribu qui habitait là.".
Instead of taking accessoirescamp, say "Ce genre d[']objet un peu archaïque ne vous sera d[']aucune utilité dans le moment présent.".
Plateau is a room. The printed name of Plateau is "Le plateau de l[']ancien site de Sarvegne".
The description of Plateau is "Vous êtes sur le plateau qui correspondait à l[']ancienne ville de Sarvegne, aux temps antiques. [if Plateau is not visited]Ce plateau fait environ la taille d[']un stade, et présente quelques traces de végétation. Il y a également quelques gros rochers de taille imposante, mais vous ne venez pas ici pour faire de la géologie.[end if] Des trous descendent vers le réseau de grotte sous le plateau.".
PlateauFake is scenery in Plateau.
Understand "grottes/grotte/plateau/trou/foyer/sarvegne/ruines/plantes/arbustes/trous/vegetation/rochers/roche" as plateauFake. The printed name of PlateauFake is "plateau". The description of plateaufake is "Ce plateau ainsi que le réseau de grottes qui passe en dessous représentaient le premier foyer de peuplement de la cité de Sarvegne. Mais la cité a depuis complètement disparu, le plateau est entièrement vide à l[']exception de quelques arbustes, plantes et baies qui restent là.".
Navette is in Plateau. Navette is a female vehicle. The printed name of navette is "la navette".
Instead of entering navette, try chatting mecanicien.
baie is a kind of thing. BaieJaune is a baie. The printed name of BaieJaune is "des baies jaunes". BaieJaune is in plateau. The description of BaieJaune is "Ces baies jaunes sont presque lumineuses.". Understand "baies/baie/jaune/jaunes" or "baies jaunes" as baiejaune.
Instead of taking baiejaune, say "Vous n[']avez pas le temps de déguster les spécialités locales."
Grottes is down from Plateau.
The description of Grottes is "[if Grottes is not visited]L[']entrée principale descend en pente douce. Anita vous a expliqué où elle avait caché les artefacts, et vous reconnaissez facilement les lieux qu[']elle vous a décrits. [end if]Vous êtes dans une salle qui fut autrefois un grand hall d[']accueil princier. Le réseau de grottes s[']étend bien au-delà de ce que vous voyez, et des ouvertures partent un peu partout. Mais Anita vous a dit de ne pas quitter le chemin qui s[']étend sur votre gauche tout à l[']entrée, et vous atteindrez directement les artefacts. La sortie se trouve en remontant la rampe[if Grottes is not visited] que vous venez d[']emprunter[end if]."
Grottes2 is west from Grottes.
The description of grottes2 is "[if location is not visited]Cette partie se prolonge encore jusqu[']à aboutir à une salle de taille moyenne, mais emplie d[']objets hétéroclites. Visiblement les scientifiques ont décidé de stocker là certaines de leurs diverses découvertes en attendant que la situation vis à vis du gouvernement de Sarvegne se débloque[otherwise]Une salle de taille moyenne[end if].".
The printed name of grottes2 is "La salle de stockage des reliques.".
a relique is a kind of thing.
Instead of attacking a relique, say "Ce sont des objets anciens, vous devez normalement les respecter."
Instead of touching a relique, say "Vous retournez l[']objet dans tous les sens, mais pour vous qui n[']êtes pas un spécialiste, il ne vous livrera pas facilement son secret.".
Instead of inserting a relique into sacdos, say "Vous ne pouvez mettre ce genre d[']objet ancien dans un sac à dos sans aucune protection, vous devriez utiliser une valise capitonnée à la place.".
artefake is scenery relique in grottes2. The description of artefake is "Divers artefacts.". The printed name of artefake is "des artefacts anciens". Understand "artefact" or "tout" as artefake.
the artefact1 is female scenery relique in grottes2. The description of artefact1 is "Une carte hexagonale, en cuir rouge, avec seulement six points cardinaux, d[']un territoire inconnu.". The printed name of artefact1 is "carte ancienne". Understand "carte/cuir" or "carte ancienne" as artefact1.
the artefact2 is scenery relique in grottes2. The description of artefact2 is "Ceci n[']est qu[']une petite partie d[']un bouclier ancien, où on trouve des incrustations dans un autre métal, sans doute de l[']argent, qui forment des points semblant disposés aléatoirement.".The printed name of artefact2 is "fragment de bouclier ancien". Understand "bouclier/points/argent" or "bouclier ancien" as artefact2.
the artefact3 is scenery relique in grottes2. The description of artefact3 is "Ce couteau a sur son manche et sa lame une série de pentagrammes et de croissants occultes gravés. La lame est torsadée, il semble utilisé pour accomplir des rituels anciens.".The printed name of artefact3 is "couteau". Understand "couteau" or "lame/pentagrammes" as artefact3.
the artefact4 is female scenery relique in grottes2. The description of artefact4 is "Une boîte en lapis-lazuli et avec des décorations ainsi que le fermoir en bronze, on y voit des motifs géométriques en forme de roues qui donnent l[']impression de tournoyer de façon hypnotique.".The printed name of artefact4 is "petite boîte". Understand "boite/lazuli" or "petite boite" as artefact4.
Instead of opening artefact4, say "Elle est fermée par un dispositif dont vous ignorez tout.".
the artefact5 is scenery relique in grottes2. The description of artefact5 is "Un vase en terre cuite, sur lequel est peint un sanglier doré.".The printed name of artefact5 is "vase". Understand "vase en terre cuite" or "terre/vase/sanglier" as artefact5.
the artefact6 is female scenery relique in grottes2. The description of artefact6 is "Une croix miniature, dans le genre de celle que l[']on utilisait dans les anciens temps pour crucifier les criminels.".The printed name of artefact6 is "croix". Understand "croix" or "crucifix" as artefact6.
the artefact7 is female scenery relique in grottes2. The description of artefact7 is "Une pointe de flèche en bronze.".The printed name of artefact7 is "pointe de flèche". Understand "pointe" or "fleche" or "pointe de fleche" as artefact7.
[Include Basic Screen Effects by Emily Short. Include Menus by Emily Short.
Table of Amusing Matter
| title | subtable | description | toggle |
| "Epilogue" | a table-name | "Anita ouvre le petit coffret en lapis-lazuli. Elle en sort une plaque de cuivre gravé qu[']elle lit puis qu[']elle vous tend. Il y figure ces lignes :[line break][line break][italic type] | |
| Je garde avec moi ce bouclier d[']étoiles[line break] | |||
| Qui nous protège d[']une bannière étoilée[line break] | |||
| Située alors si loin qu[']elle nous paraissait inoffensive[line break] | |||
| Mais nous avons traversé des lieues dans l[']espace[line break] | |||
| Puis conquit des terres hospitalières et libres[line break] | |||
| Nos chariots roulant inlassablement sur l[']herbe et le sable[line break] | |||
| Nos arcs et nos flèches toujours à notre portée[line break] | |||
| Des ennemis veulent nous passer au fil de leur épée[line break] | |||
| et nous imposer une religion nouvelle[line break] | |||
| Mais quoi qu[']il en soit nous resterons toujours nous-même.[line break][roman type]" | a rule | ||
| "Military Revisions" | a table-name | "Did you try... [paragraph break] allying a Greek city-state with the Persians? (try >MEDIZE) [line break] playing Athens as a land-based power?" | a rule |
Rule for amusing a victorious player:
change the current menu to the Table of Amusing Matter;
change the current menu title to "Epilogue";
carry out the displaying activity;
clear the screen.]
Rule for amusing a victorious player: say "Anita ouvre le petit coffret en lapis-lazuli. Elle en sort une plaque de cuivre gravé qu[']elle lit puis qu[']elle vous tend. Il y figure ces lignes :[line break][line break][italic type]
Je garde avec moi ce bouclier d[']étoiles[line break]
Qui nous protège d[']une bannière étoilée[line break]
Située alors si loin qu[']elle nous paraissait inoffensive[line break]
Mais nous avons traversé des lieues dans l[']espace[line break]
Puis conquit des terres hospitalières et libres[line break]
Nos chariots roulant inlassablement sur l[']herbe et le sable[line break]
Nos arcs et nos flèches toujours à notre portée[line break]
Des ennemis veulent nous passer au fil de leur épée[line break]
et nous imposer une religion nouvelle[line break]
Mais quoi qu[']il en soit nous resterons toujours nous-même.[line break][roman type]".
[Index map with EPS file,
room-name-length set to 15,
route-thickness set to 2,
room-outline set to off,
map-outline set to off,
route-colour set to "Chocolate",
room-colour set to "Burly Wood",
title set to "Sarvegne",
font set to "Baskerville".]