Choisir le nom de son personnage ?

Pour discuter des langages que nous utilisons pour réaliser nos jeux : problèmes, solutions, suggestions...

Modérateurs: Stormi, Otto Grimwald

Choisir le nom de son personnage ?

Messagepar StephaneF le Mer Sep 26, 2012 4:16 pm

Bonjour les gens

Je suis en train de programmer un RPG sous Inform 7 et comme il se doit, avec création de personnage en début de partie. Sexe, caractéristiques, compétences, etc.

J'aimerais permettre au joueur de choisir son nom. Qu'il soit affiché ensuite durant le jeu, lorsqu'il regarde son passeport ou que sais je.

Et je n'ai la MOINDRE idée, pas le plus petit début d'idée, de comment faire.

Quelqu'un ici saurait-il ? merci d'avance !
Avatar de l’utilisateur
StephaneF
Grand Ancien
 
Messages: 547
Inscription: Jeu Déc 27, 2007 3:53 pm
Localisation: Moselle

Re: Choisir le nom de son personnage ?

Messagepar Mule hollandaise le Ven Sep 28, 2012 6:14 pm

En I6 y'a une commande "changePlayer(object)" : tu crées un objet "object" avec un nom et une description, et tu transmutes le joueur à l'intérieur, ce qui fait que la réponse à "> x moi" (par exemple) sera la description qui fut attribuée à l'objet. Peut-être y'a-t-il une commande comme ça (pour "changer le joueur de corps") pour I7 ? Désolé de ne pas pouvoir aider un peu plus, je ne connais pas I7 !
Mule hollandaise
Grand Ancien
 
Messages: 1124
Inscription: Mar Aoû 29, 2006 10:57 pm

Re: Choisir le nom de son personnage ?

Messagepar Otto Grimwald le Ven Sep 28, 2012 7:29 pm

j'ai enfin retrouvé, dans l'exemple 405 du manuel :

Code: Tout sélectionner
"Identity Theft"

The player's forename is an indexed text that varies. The player's full name is an indexed text that varies.

When play begins:
   now the command prompt is "What is your name? > ".

To decide whether collecting names:
   if the command prompt is "What is your name? > ", yes;
   no.

After reading a command when collecting names:
   if the number of words in the player's command is greater than 5:
      say "[paragraph break]Who are you, a member of the British royal family? No one has that many names. Let's try this again.";
      reject the player's command;
   now the player's full name is the player's command;
   now the player's forename is word number 1 in the player's command;
   now the command prompt is ">";
   say "Hi, [player's forename]![paragraph break]";
   say "[banner text]";
   move the player to the location;
   reject the player's command.

[We also want to postpone the proper beginning of the game until we've gotten the name:]

Instead of looking when collecting names: do nothing.

Rule for printing the banner text when collecting names: do nothing.

Rule for constructing the status line when collecting names: do nothing.

Your Bedroom is a room. The printed name of Your Bedroom is "[player's forename]'s Bedroom".

The player carries a letter. The description of the letter is "Dear [player's full name], [paragraph break]You have won the Norwegian Daily Lottery! ...".

Avatar de l’utilisateur
Otto Grimwald
Très Ancien
 
Messages: 3028
Inscription: Mar Aoû 24, 2004 12:02 pm

Re: Choisir le nom de son personnage ?

Messagepar StephaneF le Mar Oct 09, 2012 2:54 pm

J'ai développé mon propre truc, beaucoup plus court :

The nomperso is an indexed text that varies.

A person has a number called pointsrestants.

Texting is an action applying to one topic. Understand "[text]" as texting.

Every turn when the creationstep of the player is 2: [ ---> indique juste l'étape dans la création du perso, dans le jeu sur lequel je bosse ]
now the pointsrestants of the player is a random number between 250 and 350;
say "[line break][bold type]CREATION DU PERSONNAGE[roman type][line break]";
say "[line break]Quel est votre nom ?".

Instead of doing anything when the creationstep of the player is 2:
now the nomperso is the topic understood;
say "[line break]Vous vous appelez [nomperso].";
now the creationstep of the player is 3.
Avatar de l’utilisateur
StephaneF
Grand Ancien
 
Messages: 547
Inscription: Jeu Déc 27, 2007 3:53 pm
Localisation: Moselle


Retourner vers Questions techniques et aide pour votre code

Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 1 invité