Les Heures du vent
Une fiction interactive par Eric Forgeot (2007) - Code source Inform 7
Home pageContents
Previous
Next
Complete text Chapter 3 - l ' auberge
a LitChambreAuberge is enterable supporter in ChambreAuberge. The printed name of LitChambreAuberge is "lit". Understand "lit" as LitChambreAuberge. [The LitChambreAuberge is fixed in place. 'implicite'? TODO check]
The sac is a player's holdall. The sac is wearable.
The sac is in CouloirAuberge.
Understand "sac/besace" as sac.
A clou is a kind of thing. In the Void are 14 clous.
To bring a clou to the location:
let item be a random clou in the Void;
move item to the location.
To bring (n - a number) clous to the location:
repeat with i running from 1 to n
begin;
bring a clou to the location;
end repeat.
To bring a clou to the sac:
let item be a random clou carried by the player;
move item to the sac.
To bring (n - a number) clous to the sac:
repeat with i running from 1 to n
begin;
bring a clou to the sac;
end repeat.
After taking clou when clou was in location:
if the sac is held by the player
begin;
bring a clou to the sac;
say "Il mit un clou dans le sac pour se débarrasser.";
end if.
Instead of taking clou when clou was in sac:
if a clou (called clou_perdu) is in location
begin;
say "Ok.";
move clou_perdu to sac;
otherwise;
say "Il valait mieux pour lui garder ces broutilles au fond de son son sac, aussi il n[']y toucha plus.";
end if.
To bring a clou to the nettoyeur:
let item be a random clou in the sac;
move item to the nettoyeur.
To bring (n - a number) clous to the nettoyeur:
repeat with i running from 1 to n
begin;
bring a clou to the nettoyeur;
end repeat.
Instead of examining the murs when location is ChambreAuberge for the first time:
say "Il trouva un clou fixé dans un des murs.";
bring 1 clous to the location.
Instead of examining the sac when location is CouloirAuberge for the first time:
say "Son sac se trouvait là, suspendu au mur.";
try examining the murs.
Instead of examining the murs when location is CouloirAuberge for the first time:
say "Il y avait un clou fixé dans un des murs, qui pouvait servir à suspendre diverses affaires.";
bring 1 clous to the location.
Instead of searching the murs, try examining the murs.
Instead of examining the murs when location is AubergePrincipale for the first time:
say "Non, il n[']y avait pas de clou ici.";
bring 1 clous to the location.
Instead of examining the banc when location is Place31 for the first time:
say "Il trouva deux clous qui ressortaient d[']un des bancs.";
bring 2 clous to the location.
Instead of examining the banc when location is Place31 for the second time:
say "Il trouva trois clous qui dépassaient d[']un autre banc.";
bring 3 clous to the location.
Instead of searching the banc, try examining the banc.
In RuePavee43 is 2 clous.
Instead of searching Fontaine33 for the second time:
say "Il y avait un petit clou dans l[']eau.";
bring 1 clous to the location;
remove 3clous from play.
[Before giving two clous to nettoyeur, say "no no no".]
[Before listing contents: group clou together giving articles.]
The description of clou is "C[']était un clou assez ordinaire, [one of]il était bien brillant[or]il était un peu rouillé[or]il était un peu tordu[or]il avait sa pointe un peu émoussée[at random]."
[todo : voir commentaire pour clou fixé dans le mur]
Understand "clou/clous/pointe" as clou.
The description of ChambreAuberge is "[if Player is on LitChambreAuberge for the first time]Il restait encore quelques heures avant le lever complet du soleil. La matinée allait s[']annoncer riche en événements, et sans doute passablement fatigante. Fallait-il se rendormir, ou au contraire se lever et travailler un peu, à préparer cette rencontre pour laquelle il avait parcouru toutes ces lieues ?[line break][end if][if volets are opened and Nuit1 is happening]La lumière de la lune filtrait à travers les rideaux de la fenêtre.[line break][end if]La chambre était sans ornement, et les murs recouverts de chaux semblaient un peu vides.[if volets are opened] Le seul tableau et élément de décoration était d[']ailleurs l[']ouverture de la fenêtre.[end if]". The printed name of ChambreAuberge is "Chambre".
Before going west from CouloirAuberge:
if partie1 is happening
begin;
continue the action;
otherwise;
say "La chambre ne fut plus disponible lorsqu[']il revint à ce moment-là, la porte d[']ailleurs avait été verrouillée.";
stop the action;
end if.
Understand "descendre du lit" as exiting. [BUG]
[Understand "descendre du lit" as a mistake ("Il lui suffisait juste de descendre."). BUG ]
Instead of going down when location is ChambreAuberge, try exiting.
Volets are a kind of thing. Fenetre is a kind of thing.
Volets are usually openable. Fenetre is usually openable.
Volets are usually open. Fenetre is usually open.
Understand "volet/volets" as volets.
Understand "fenetre/fenetres/ouverture" as fenetres.
volets1 are scenery volets in ChambreAuberge. Volets1 are opened. The printed name of volets1 is "des volets". The description of volets1 is "Des volets formés par d[']épaisses lames de bois sombre.".
rideaux1 are scenery in ChambreAuberge. The printed name of rideaux1 is "des rideaux". The description of rideaux1 is "Des rideaux en lin, passés dans une teinture grossière qui devint au fil du temps d[']une couleur indéfinissable.". Understand "rideaux" as rideaux1.
fenetre1 is female scenery fenetre in ChambreAuberge. The printed name of fenetre1 is "une fenêtre". The description of fenetre1 is "Une fenêtre en bois clair.".
Instead of closing some volets (called self):
if self are opened
begin;
now self are not opened;
say "Il ouvrit la fenêtre, et ferma les volets.";
otherwise;
say "C[']était déjà fermé, et bien comme ça.";
end if.
Instead of opening volets (called self):
if self are opened
begin;
say "Les volets était déjà ouverts.";
otherwise;
say "Il ne voulut pas entendre de nouveaux le vent frapper ces volets, aussi il les laissa fermés.";
end if.
Instead of closing fenetre (called self):
if self are opened
begin;
now self are not opened;
say "Il ouvrit la fenêtre, ferma les volets, et referma également la fenêtre.";
otherwise;
say "Les volets étaient déjà clos, il n[']y a aucune raison de faire cela.";
end if.
Instead of opening fenetre1, try closing volets1. [TODO : bug volets/fenetre]
Instead of closing fenetre1, try closing volets1.
Nuit is a thing.
Nuit can be over.
Instead of sleeping during Nuit1:
if volets are opened
begin;
say "C[']était impossible avec le bruit du vent au dehors.";
otherwise;
Now the player is on LitChambreAuberge;
say "Il s[']endormit jusqu[']au lendemain, d[']un sommeil profond et sans rêve.";
Now the Nuit is over;
move player to ChambreAuberge;
end if.
table_chambre is female supporter in ChambreAuberge. The printed name of table_chambre is "une table". The description of table_chambre is "Une simple table qui servait de bureau. L[']auberge n[']était pas assez riche pour fournir une chaise supplémentaire, si les voyageurs de passage voulaient travailler au bureau, il fallait s[']asseoir sur le lit. Ils auraient sans doute pu fournir au moins un tabouret...". Understand "table" as table_chambre.
Instead of listening during Nuit1, try listening to vent.